@ECHO off
REM 2017-04-11: Generate list of all files as quoted CSV, with import headers
REM 2017-06-30: Datetime independent of local format; exclude .BAT from list

SET filename=!_ListRevisionFiles.csv
REM Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

REM Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      SET _yyyy=%%L
      SET _mm=00%%J
      SET _dd=00%%G
      SET _hour=00%%H
      SET _minute=00%%I
      SET _second=00%%K
)
:s_done

REM Pad digits with leading zeros
      SET _mm=%_mm:~-2%
      SET _dd=%_dd:~-2%
      SET _hour=%_hour:~-2%
      SET _minute=%_minute:~-2%
      SET _second=%_second:~-2%

REM Display the date/time in ISO 8601 format:
SET _isodate=%_yyyy%-%_mm%-%_dd%T%_hour%-%_minute%-%_second%
SET filename=!_ListRevisionFiles_%_isodate%.csv
:s_error
ECHO RevisionFile,Class,Owner,Type,Number > %filename%
ATTRIB +H %0
ATTRIB +H %filename%
FOR /r %%a IN (*.*) do ECHO ^"%%a^" >> %filename%
ATTRIB -H %filename%
ATTRIB -H %0
ECHO.
ECHO   The output file '%filename%' is now
ECHO   located in the same folder where you saved '_GetFileInventory.bat'
ECHO.
pause